一台云服务器windows篇：12、RustDesk Server OSS

install.bat

@echo off
rem nssm.exe在同一个目录中

call :install hbbs
call :install hbbr
echo 使用 nssm edit hbbs 编辑，追加启动参数 -r y.z
goto batEnd

:install
rem logDir目录要有Network Service的NTFS权限： %~dp0logs C:\inetTmp\RDSLogs  
set logDir=C:\inetTmp\RDSLogs
"%~dp0nssm.exe" install "%1" "%~dp0%1.exe" "-k OSTqGaRqja"
"%~dp0nssm.exe" set "%1" DisplayName "RustDesk %1 server"
REM "%~dp0nssm.exe" set "%1" Description "RustDesk %1 server"
"%~dp0nssm.exe" set "%1" Start SERVICE_AUTO_START
"%~dp0nssm.exe" set "%1" ObjectName NetworkService
"%~dp0nssm.exe" set "%1" Type SERVICE_WIN32_OWN_PROCESS
"%~dp0nssm.exe" set "%1" AppThrottle 1000
"%~dp0nssm.exe" set "%1" AppExit Default Restart
"%~dp0nssm.exe" set "%1" AppRestartDelay 0
"%~dp0nssm.exe" set "%1" AppStdout "%logDir%\%1_out.log"
"%~dp0nssm.exe" set "%1" AppStderr "%logDir%\%1_err.log"
goto :eof

:batEnd
"%~dp0nssm.exe" edit hbbs
"%~dp0nssm.exe" start hbbs
"%~dp0nssm.exe" start hbbr

uninstall.bat

@echo off
call :uninstall hbbs
call :uninstall hbbr
goto batEnd

:uninstall
"%~dp0nssm.exe" stop %1
"%~dp0nssm.exe" remove %1

:batEnd

页： 1 2